Code Life

chakemiです。先日久しぶりにFLARToolKitに触ったら、ちょっと3Dで遊んでみたくなりました。

ちゃんと勉強しようと思ったら、もうPapervision3Dはないと思い
AWAY3D version3.6.0を使ってみました。

 

開発環境：
Windows7
FlexSDK4.5.1
FlashDevelop4
AWAY3D version3.6.0

こちらからAWAY3Dをダウンロード
http://away3d.com/download/
 
プロジェクトを作成してダウンロードしたパッケージの
srcディレクトリに対してクラスパスを設定します。

 
ではさっそく、Collada形式のファイルを表示してみます。

Papervision3DではDAEクラスでオブジェクトを作成し
ファイルを読み込んでsceneに追加してましたが、
AWAY3DではLoader3Dでいったんロードし、
正常にロードが行われたモデルをObjectContainer3Dとして
返すので、そのオブジェクトをsceneに追加するようです。

こんな感じで。

package  
{
     import away3d.containers.ObjectContainer3D;
     import away3d.containers.View3D;
     import away3d.events.Loader3DEvent;
     import away3d.loaders.Collada;
     import away3d.loaders.Loader3D;
     import flash.display.Sprite;
     import flash.events.Event;

     public class Main extends Sprite 
     {
          protected var car:ObjectContainer3D;
          protected var view:View3D;

          public function Main() 
          {
               super();
               this.addEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
          }

          protected function onAddedToStage(event:Event):void 
          {
               createChildren();
               loadModel();
               startRendering();
          }

          protected function createChildren():void 
          {
               view = new View3D({x:stage.stageWidth/2, y:stage.stageHeight/2});
               addChild(view);
          }

          protected function loadModel():void 
          {
               var loader3D:Loader3D = Collada.load("car_a/z34_a.dae");
               loader3D.addEventListener(Loader3DEvent.LOAD_SUCCESS, onModelLoadSuccess);
          }

          protected function onModelLoadSuccess(event:Loader3DEvent):void 
          {
               car = event.loader.handle as ObjectContainer3D;
               car.scale(50);
               car.rotateTo(0, 40, 0);
               car.moveDown(3);
               view.scene.addChild(car);
          }

          protected function startRendering():void 
          {
               addEventListener(Event.ENTER_FRAME, onRenderTick);
          }

          protected function onRenderTick(event:Event = null):void 
          {
               view.render();
          }
     }
}

 

 
表示できました。

version4.0.110915 AlphaではFlashPlayer11に対応し、stage3D API機能を使うことが出来る様なのでいつかのタイミングで触れてみたいと思います。